#e
#Title[zNu炵΂܂킷[v]
#Text[񂷂ȁB]
#ScriptVersion[2]

script_enemy_main
{
	let scroll=0;
	let flag=0;
	let angle=0;
	let cx=GetCenterX();
	let cy=GetCenterY();
	let boss=GetCurrentScriptDirectory~"img\boss7-2.png";
	let eye=GetCurrentScriptDirectory~"img\bg7-1.png";
	let asa=GetCurrentScriptDirectory~"img\bg7-2.png";
	LoadUserShotData(GetCurrentScriptDirectory~"shot.txt");
	@Initialize
	{
		SetScore(30000);
		SetLife(300);
		SetDamageRate(10,0);
		SetMovePosition02(cx,cy-120,60);
		SetTimer(80);
		SetInvincibility(60);
		LoadGraphic(boss);
		LoadGraphic(eye);
		LoadGraphic(asa);
		LoadGraphic(GetCurrentScriptDirectory~"img\enemy\magic.png");
		shottask;
		shottask2;
		subtask;
		drawtask;
		bombtask;
		CutIn(YOUMU,"zNu炵΂܂킷[v",0,0,0,0,0);
	}
	@MainLoop
	{
		yield;
		angle++;
	}
	@Finalize
	{
		loop(16)
		{
			CreateItem(ITEM_SCORE,GetX+rand(-30,30),GetY+rand(-30,30));
		}
		DeleteGraphic(boss);
		DeleteGraphic(eye);
		DeleteGraphic(asa);
		DeleteGraphic(GetCurrentScriptDirectory~"img\enemy\magic.png");
	}
	@DrawLoop
	{
		SetTexture(boss);	
		if(flag==1)
		{
			SetGraphicRect(52,0,81,63);
		}
		else if(flag==2)
		{
			SetGraphicRect(24,0,52,63);
		}
		else
		{
			SetGraphicRect(0,0,24,63);
		}
		SetGraphicScale(1,1);
		SetGraphicAngle(0,0,0);
		DrawGraphic(GetX,GetY);
	}
	@BackGround
	{
		SetColor(128,128,128);
		SetTexture(eye);	
		SetGraphicRect(0,0,384,448);
		SetAlpha(255);
		SetGraphicScale(1,1);
		SetGraphicAngle(0,0,0);
		DrawGraphic(cx,cy);
		SetColor(255,255,255);
		SetTexture(asa);	
		SetGraphicRect(0,0,888,189*5);
		SetAlpha(64);
		SetGraphicScale(0.5,0.75);
		SetGraphicAngle(0,0,0);
		DrawGraphic(cx+scroll,cy);
		DrawGraphic(cx+scroll-444,cy);
		if(scroll>444)
		{
			scroll=0;
		}
	}
	task shottask
	{
		wait(240);
		loop
		{
			HomingShot(2,GetAngleToPlayer,1,false, 67);
			angle++;
			wait(90);
		}
	}
	task shottask2
	{
		wait(90);
		loop
		{
			let angle=0;
			loop(32)
			{
				CreateShot01(cx,cy,1.4,angle,77,10);
				angle+=11.25;
			}
			wait(120);
		}
	}
	task subtask
	{
		wait(60);
		CompusLaser(cx,cy,0,128,10,RED01,0);
		CompusLaser(cx,cy,180,128,10,WHITE01,0);
		loop
		{
			SetPlayerX(GetPlayerX+1*cos(angle));
			SetPlayerY(GetPlayerY+1*sin(angle));
			yield;
		}
	}
	task drawtask
	{
		let x=0;
		loop
		{	
			if(GetX>x+0.5)
			{
				flag=1;
			}
			else if(GetX<x-0.5)
			{
				flag=2;
			}
			else
			{
				flag=0;
			}
			x=GetX;
			scroll++;
			yield;
		}
	}
	task bombtask
	{
		loop
		{
			if(OnBomb)
			{
				SetAlpha(64);
				SetDamageRate(0,0);
			}
			else
			{
				SetAlpha(255);
				SetDamageRate(10,0);
				SetCollisionA(GetX(),GetY(),24);
				SetCollisionB(GetX(),GetY(),24);
			}
			yield;
		}
	}
	task CompusLaser(let x, let y, let angle2, let length,let width, let graphic, let delay)
	{
		let count=0;
		let obj = Obj_Create(OBJ_LASER);
		Obj_SetPosition(obj, x, y);
		Obj_SetSpeed(obj, 0);
		Obj_SetAngle(obj, angle+angle2);
		ObjShot_SetGraphic(obj, graphic);
		ObjShot_SetDelay(obj, delay);
		ObjLaser_SetLength(obj, length);
		ObjLaser_SetWidth(obj, width);
		ObjLaser_SetSource(obj, false);
		Obj_SetAutoDelete(obj,false);
	        loop(delay){ yield; }
		while(!Obj_BeDeleted(obj))
		{
			Obj_SetAngle(obj,angle+angle2);
			count++;
			yield;
		}
	}
	task HomingShot(let speed,let angle,let carb,let bomb, let graphic)
	{
		let obj = Obj_Create(OBJ_SHOT);
		Obj_SetPosition(obj,GetX, GetY);
		Obj_SetSpeed(obj, speed);
		Obj_SetAngle(obj, angle);
		ObjShot_SetGraphic(obj, graphic);
		ObjShot_SetDelay(obj, 0);
		ObjShot_SetBombResist(obj, bomb);
		loop(180)
		{
			let angleToPlayer = atan2(GetPlayerY-Obj_GetY(obj), GetPlayerX-Obj_GetX(obj));
			if(Obj_BeDeleted(obj))
			{
				break;
			}
			if(sin(angleToPlayer - Obj_GetAngle(obj))>0)
			{
				Obj_SetAngle(obj, Obj_GetAngle(obj) + carb);
			}
			else
			{
				Obj_SetAngle(obj, Obj_GetAngle(obj) - carb);
			}
			Obj_SetSpeed(obj, speed);
			fire(Obj_GetX(obj),Obj_GetY(obj));
			if(speed<5){speed+=0.01}
			yield;
		}
	}
	task fire(let x, let y)
	{
		let obj = Obj_Create(OBJ_SHOT);
		Obj_SetPosition(obj, x+rand(-7,7), y+rand(-7,7));
		Obj_SetSpeed(obj, 0.3);
		Obj_SetAngle(obj, rand(0,360));
		ObjShot_SetGraphic(obj, 131);
		ObjShot_SetDelay(obj,0);
		Obj_SetCollisionToPlayer(obj,false);
		Obj_SetAlpha(obj,240);
		Obj_SetAutoDelete(obj,false);
		ObjShot_FadeDelete(obj);
	}
	function wait(w) 
	{
		loop(w)
		{
			yield;
		}
	}
}